Spice models
I went away trying to learn Spice. It's too spicy for me. I can't handle it. On a serious note. What am I suppose to do with it? Say I want to play around with R1 R2 C1 values. Where do I put the numbers? What functions am I suppose to use? Sorry Wayne. I am a bad student. Even your "student version" is too hard for me.
The nomenclature in my Spice models is the same as the nomenclature in my schematics. So you can easily identify R1, R2 and C1 values. They're exactly as shown.
Below are some Spice models.
1. The original 2nd/3rd Pi crossover
2. The newer 3rd/3rd Pi crossover
3. A model of an old Eminence MD2001 compression driver on an H290 horn
The early crossover worked very well, but I optimized it later with help using the Smith & Larson ICD. This improved summing in the crossover region, largely because tweeter circuit peaking is reduced. There is also some additional delay on the woofer, although not as much as you might expect moving up an order. The crossover point was changed, not just the slope, and this resulted in less delay shift.
You may notice that the Spice models of the crossovers only use a simple Re/Le model for the driver. This is because the frequency of diaphragm resonance and the first quarter wave modes are below the crossover frequency. However, the fact that some optimizations improved the results may mean that it would have been good to include the resonances in the model. This is a mute point, since the S&L ICD uses a ZMA file of measured impedance for the load.
The last Spice model shown is of a compression driver on a horn, with resonances included to simulate diaphragm resonance and the first couple quarter-wave modes.
====== 2nd/3rd order Pi crossover =============================
Pi Speaker Crossover
! 10dB tweeter attenuation at crossover frequency
! for three octaves; 6dB/octave augmentation three
! octaves above crossover frequency
!
! R1=16 ohms, R2=16 ohms, C1=0.47uF
!
! Model for standard "2 way" loudspeaker crossover
! with 2nd order low pass woofer filter and
! 3rd order high pass tweeter filter
! with 10dB compensation circuit
!
! Input across nodes 0 & 5, positive to 5
! Tweeter output across 1 & 2, positive to 1
! Woofer output across 0 & 6, positive to 6
!
! component (+)node (-)node value
vin 5 0 AC 1.0
! Woofer virtual circuit
R3 6 7 6
L3 7 0 1.0mH
! Tweeter virtual circuit
R4 1 8 6
L4 8 0 0.1mH
! Compensation components
R1 3 1 16
C1 3 1 0.47uF
! Pre-compensation load
R2 3 0 16
! RC damper for woofer
R11 6 15 8
C11 15 0 22uF
! Crossover Network
L2 5 6 1.0mH
C4 6 0 10uF
C2 5 4 8uF
L1 4 0 0.6mH
C3 4 3 22uF
====== 3rd/3rd order Pi crossover =============================
Pi Speaker Crossover
! 10dB tweeter attenuation at crossover frequency
! for three octaves; 6dB/octave augmentation three
! octaves above crossover frequency
!
! R1=16 ohms, R2=16 ohms, C1=0.47uF
!
! Model for standard "2 way" loudspeaker crossover
! with 3rd order low pass woofer filter and
! 3rd order high pass tweeter filter
! with 10dB compensation circuit
!
! Input across nodes 0 & 5, positive to 5
! Tweeter output across 1 & 2, positive to 1
! Woofer output across 0 & 6, positive to 6
!
! component (+)node (-)node value
vin 5 0 AC 1.0
! Woofer virtual circuit
R5 6 7 6
L5 7 0 1.0mH
! Tweeter virtual circuit
R4 1 8 6
L4 8 0 0.1mH
! Compensation components
R1 3 1 16
C1 3 1 0.47uF
! Pre-compensation load
R2 3 0 16
! RC damper for woofer
R11 6 15 8
C11 15 0 20uF
! Crossover Network
L2 5 9 1.5mH
C4 9 0 20uF
L3 9 6 0.5mH
C2 5 4 6.8uF
L1 4 0 1.0mH
C3 4 3 20uF
====== Compression driver on horn =============================
Tweeter reactance
vin 1 0 AC 100.0
! source impedance
R1 1 6 60
! tweeter virtual circuit (Eminence MD2001)
! voice coil reactance
R4 6 10 6.6
L4 10 11 0.1mH
! mechanical reactance (on H290)
C6 11 12 25uF
L6 11 12 2.5mH
R6 11 12 100
C7 12 13 12.5uF
L7 12 13 1.25mH
R7 12 13 100
C8 13 0 6.25uF
L8 13 0 0.625mH
R8 13 0 100
R9 11 0 20
C9 11 0 66uF